From 176ef62d2f4898134a4f681b8415fc0d90b5913e Mon Sep 17 00:00:00 2001
From: René 'Necoro' Neumann <necoro@necoro.net>
Date: Mon, 26 Aug 2013 22:52:55 +0200
Subject: Radicale bump

---
 app-office/radicale/radicale-0.8.ebuild | 73 +++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 app-office/radicale/radicale-0.8.ebuild

(limited to 'app-office/radicale/radicale-0.8.ebuild')

diff --git a/app-office/radicale/radicale-0.8.ebuild b/app-office/radicale/radicale-0.8.ebuild
new file mode 100644
index 0000000..575f90a
--- /dev/null
+++ b/app-office/radicale/radicale-0.8.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_2,3_3} )
+PYTHON_REQ_USE="ssl?"
+
+inherit distutils-r1 user
+
+MY_PN="Radicale"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A simple CalDAV calendar server"
+HOMEPAGE="http://www.radicale.org/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE="fastcgi ldap sql ssl"
+
+RDEPEND="ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
+		fastcgi? ( dev-python/flup[${PYTHON_USEDEP}] )
+		sql? ( dev-python/sqlalchemy[${PYTHON_USEDEP}] )"
+
+# radicale's authentication against PAM is not possible here:
+# Gentoo has not included the package
+# also it seems old, which is bad with respect to
+# http://web.nvd.nist.gov/view/vuln/detail?vulnId=CVE-2012-1502
+
+S=${WORKDIR}/${MY_P}
+
+RDIR=/var/lib/radicale
+LDIR=/var/log/radicale
+
+PATCHES=( "${FILESDIR}"/${P}-config.patch )
+
+pkg_setup() {
+	enewgroup radicale
+	enewuser radicale -1 -1 ${RDIR} radicale
+}
+
+python_install_all() {
+	# delete the useless .rst, so that it is not installed
+	rm README.rst
+
+	# init file
+	newinitd "${FILESDIR}"/radicale.init.d radicale || die
+
+	# directories
+	diropts -m0750
+	dodir ${RDIR}; fowners radicale:radicale ${RDIR}
+	dodir ${LDIR}; fowners radicale:radicale ${LDIR}
+
+	# config file
+	insinto /etc/${PN}
+	doins config logging || die
+
+	# fcgi and wsgi files
+	insinto /usr/share/${PN}
+	doins radicale.wsgi
+	use fastcgi && doins radicale.fcgi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	einfo "Radicale now supports WSGI."
+	einfo "A sample wsgi-script has been put into ${ROOT}usr/share/${PN}."
+	use fastcgi && einfo "You will also find there an example fcgi-script."
+}
-- 
cgit v1.2.3-70-g09d2