# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
PYTHON_DEPEND="*:2.6"
SUPPORT_PYTHON_ABIS=1

inherit distutils

MY_P="${PN/r/R}-${PV}"

DESCRIPTION="A simple CalDAV calendar server"
HOMEPAGE="http://www.radicale.org/"
SRC_URI="http://www.radicale.org/src/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="ldap fastcgi ssl"

# the '>=' goes ok, as radicale supports _all_ other python version
# this includes all 3.* versions
DEPEND="ssl? ( >=dev-lang/python-2.6.6[ssl] )
		ldap? ( dev-python/ldap )
		fastcgi? ( dev-python/flup )"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${MY_P}

src_prepare() {
	distutils_src_prepare

	sed -i -e "s/htpasswd_encoding/encoding/" ${S}/radicale/acl/htpasswd.py || die
}

src_install() {
	distutils_src_install

	# init file
	newinitd "${FILESDIR}"/radicale.init.d radicale || die

	# config file
	insinto /etc/${PN}
	doins config "${FILESDIR}"/logging || die

	# fcgi & wsgi file
	insinto /usr/share/${PN}
	doins "${FILESDIR}/radicale.wsgi"
	use fastcgi && doins "${FILESDIR}/radicale.fcgi"
}

pkg_postinst() {
	einfo "Radicale now supports WSGI."
	einfo "A sample wsgi-script has been put into
	${ROOT}usr/share/${PN}."
	if use fastcgi; then
		einfo "There you will also find an example fcgi-script."
	fi
}