# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

CMAKE_MIN_VERSION="2.8.4"

M_P="monitor-0.6"

inherit cmake-utils

DESCRIPTION="Advanced and secure webserver"
HOMEPAGE="http://www.hiawatha-webserver.org"
SRC_URI="http://www.hiawatha-webserver.org/files/${P}.tar.gz
	monitor? ( http://www.hiawatha-webserver.org/files/${M_P}.tar.gz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="debug +cache chroot ipv6 monitor +rewrite rproxy ssl tomahawk xsl"

DEPEND="
	ssl?  ( >=net-libs/polarssl-1.2 )
	xsl? ( dev-libs/libxslt
	 	dev-libs/libxml2 )
		"

RDEPEND="${DEPEND}
	monitor? ( 	virtual/cron
		=dev-lang/php-5*[mysql,xsl]
		virtual/mysql )
		"

REQUIRED_USE="monitor? ( xsl )"

PATCHES=("${FILESDIR}"/${P}-no-bundled-polarssl.patch)

src_configure() {
	if use debug; then
		CMAKE_BUILD_TYPE="RelWithDebInfo"
	else
		CMAKE_BUILD_TYPE="Gentoo"
	fi
	if use kernel_linux; then
		myargs=" -DENABLE_LOADCHECK=ON "
	fi

	mycmakeargs=(
		$(cmake-utils_use_enable cache CACHE)
		$(cmake-utils_use_enable chroot CHROOT)
		$(cmake-utils_use_enable ipv6 IPV6)
		$(cmake-utils_use_enable debug DEBUG)
		$(cmake-utils_use_enable monitor MONITOR)
		$(cmake-utils_use_enable rewrite TOOLKIT)
		$(cmake-utils_use_enable rproxy RPROXY)
		$(cmake-utils_use_enable ssl SSL)
		$(cmake-utils_use_enable xsl XSLT)
		-DLOG_DIR:STRING=/var/log/hiawatha
		-DPID_DIR:STRING=/var/run
		-DWEBROOT_DIR:STRING=/var/www/hiawatha
		-DWORK_DIR:STRING=/var/lib/hiawatha
		-DCONFIG_DIR:STRING=/etc/hiawatha
		${myargs}
		)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	newinitd "${FILESDIR}"/hiawatha.initd  hiawatha

	keepdir /var/l{ib,og}/hiawatha
	if use monitor; then
		insinto /usr/share/"${PN}"/monitor
		doins -r "${WORKDIR}"/monitor/*
		newdoc "${WORKDIR}"/monitor/README README.monitor
		newdoc "${WORKDIR}"/monitor/ChangeLog ChangeLog.monitor
	fi
}

pkg_postinst() {
	if use monitor; then
		einfo "You requested the server monitor feature. The required files have been"
		einfo "installed to /usr/share/${PN}/monitor."
		einfo "Please follow the instructions in /usr/share/${PN}/monitor/README."
	fi
}