jQuery.fn.extend do
    copy : -> @clone!remove-attr 'id class'

# Start jQuery context
<-! $

# Add
addJS = !->
    $ 'input[name=date]' .datepicker do
        dateFormat: \dd.mm.yy
        firstDay: 1

# Show
showJS = !->
    $ ".detail span" .click ->
        $ @ .prev-all \.mark:last .click!

    $ ".detail > .mark" .click ->
        if (@src.indexOf \closed) is not -1
            @src .= replace \closed \open
        else
            @src .= replace \open \closed

        $ @ .next-all \.details:first .toggle!

    $ \.details .hide!

# Categories
catsJS = !->
    counter = 0
    add_img = $ \image#add
    new_input = $ \input#new

    new_image = (new_name) ->
        # we need to copy the image to get the correct URL
        add_img.copy!
            .. .attr \src -> @src.replace \add, new_name

    $ "li > span" .click ->
        span = $ @
        input = span.next!
        img = new_image \undo
            .. .click ->
                    $ @ .remove!
                    input.fade-out \slow span.toggle

                    # reset text
                    input.val span.text!

        span.toggle!
        input.fade-in \slow -> $ @ .after img

    add_img.click ->
        input = new_input.copy!
        img = new_image \minus
            .. .click ->
                    <- $ @ .parent!fade-out \slow
                    $ @ .remove!

        input.attr \name -> @name + counter
            .remove-attr \style
            .insert-before add_img.parent!
            .wrap "<li />"

        input.parent!
            .append img
            .hide!
            .fade-in \slow input.focus