Prosody 0.8.0

1 files changed, 66 insertions, 0 deletions

diff --git a/net-im/prosody/prosody-0.8.0.ebuild b/net-im/prosody/prosody-0.8.0.ebuild
new file mode 100644
index 0000000..75bf13b
--- /dev/null
+++ b/net-im/prosody/prosody-0.8.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/prosody/prosody-0.7.0.ebuild,v 1.2 2011/03/22 20:59:44 ulm Exp $
+
+EAPI="2"
+
+inherit eutils multilib toolchain-funcs versionator
+
+MY_PV=$(replace_version_separator 3 '')
+DESCRIPTION="Prosody is a flexible communications server for Jabber/XMPP written in Lua."
+HOMEPAGE="http://prosody.im/"
+SRC_URI="http://prosody.im/downloads/source/${PN}-${MY_PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libevent ssl sql +zlib"
+
+DEPEND="net-im/jabber-base
+		>=dev-lang/lua-5.1
+		>=net-dns/libidn-1.1
+		>=dev-libs/openssl-0.9.8"
+RDEPEND="${DEPEND}
+		dev-lua/luasocket
+		ssl? ( dev-lua/luasec )
+		dev-lua/luaexpat
+		dev-lua/luafilesystem
+		sql? ( >=dev-lua/luadbi-0.5 )
+		libevent? ( dev-lua/luaevent )
+		zlib? ( dev-lua/lua-zlib )"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+JABBER_ETC="/etc/jabber"
+JABBER_SPOOL="/var/spool/jabber"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-${PV}.cfg.lua.patch"
+	sed -i "s!MODULES = \$(DESTDIR)\$(PREFIX)/lib/!MODULES = \$(DESTDIR)\$(PREFIX)/$(get_libdir)/!" Makefile
+	sed -i "s!SOURCE = \$(DESTDIR)\$(PREFIX)/lib/!SOURCE = \$(DESTDIR)\$(PREFIX)/$(get_libdir)/!" Makefile
+	sed -i "s!INSTALLEDSOURCE = \$(PREFIX)/lib/!INSTALLEDSOURCE = \$(PREFIX)/$(get_libdir)/!" Makefile
+	sed -i "s!INSTALLEDMODULES = \$(PREFIX)/lib/!INSTALLEDMODULES = \$(PREFIX)/$(get_libdir)/!" Makefile
+}
+
+src_configure() {
+	# the configure script is handcrafted (and yells at unknown options)
+	# hence do not use 'econf'
+	./configure --prefix="/usr" \
+		--sysconfdir="${JABBER_ETC}" \
+		--datadir="${JABBER_SPOOL}" \
+		--with-lua-lib=/usr/$(get_libdir)/lua \
+		--c-compiler="$(tc-getCC)" --linker="$(tc-getCC)" \
+		--cflags="${CFLAGS} -Wall -fPIC" \
+		--ldflags="${LDFLAGS} -shared" \
+		--require-config || die "configure failed"
+}
+
+src_install() {
+	DESTDIR="${D}" emake install || die "make failed"
+	newinitd "${FILESDIR}/${PN}".initd ${PN}
+}
+
+src_test() {
+	cd tests
+	./run_tests.sh
+}